OpenLink Data Spaces,
SIOC and SPARQL Guide

• To validate a particular SIOC, RDF Data Set (in plain old RDF form), you can use the W3C RDF Validation Service
• You can actually create you own Data Spaces and then experiment with these queries by opening accounts at: http://demo.openlinksw.com/ods (for very temporary and volatile usage) or http://myopenlink.net:8890/ods (for less volatile usage)
• You can run most (if not all) of the queries with minimal modification using the following SPARQL Query Services: http://demo.openlinksw.com/sparql/ (using the 'demo' user account) and http://myopenlink.net:8890/sparql/ (assuming you have an account with this service)
• Default Graph URI value used in the queries of this presentation is: http://demo.openlinksw.com/dataspace

Weblog Data Space

The following query scans an entire ODS data space (collection of many application specific data spaces) for properties associated with Entities of Type: Weblog

prefix rdf: <http://www.w3.org/1999/02/22-rdf-syntax-ns#>
prefix sioc: <http://rdfs.org/sioc/ns#>
prefix sioct: <http://rdfs.org/sioc/types#>
select distinct ?attribute
from <http://demo.openlinksw.com/dataspace>
where
  {
    ?blog a sioct:Weblog
    ?blog sioc:container_of ?post
    ?post ?attribute ?o
  }
order by ?attribute

Dump of all Weblog Posts for a given ODS Member

prefix rdf: <http://www.w3.org/1999/02/22-rdf-syntax-ns#>
prefix sioc: <http://rdfs.org/sioc/ns#>
prefix sioct: <http://rdfs.org/sioc/types#>
prefix xsd: <http://www.w3.org/2001/XMLSchema#>
prefix dct: <http://purl.org/dc/elements/1.1/>
prefix dcc: <http://purl.org/dc/terms/>
select DISTINCT ?forum_name, ?post, ?title ?cr ?url
from <http://demo.openlinksw.com/dataspace>
where
  {
   ?forum a sioct:Weblog .
   ?forum sioc:id ?forum_name.
   ?forum sioc:scope_of ?role.
   ?role sioc:function_of <http://demo.openlinksw.com/dataspace/demo#this> .
   ?forum sioc:container_of ?post.
   optional{?post dct:title ?title}.
   optional{?post dcc:created ?cr}.
   optional{?post sioc:link ?url}.
  }
order by DESC (?cr)

List of Web Services (e.g Atom Publishing (SOAP), Moveable Type ( XML-RPC) etc.) associated with Weblog Data Space Instances

prefix rdf: <http://www.w3.org/1999/02/22-rdf-syntax-ns#>
prefix svc: <http://rdfs.org/sioc/services#>
prefix sioct: <http://rdfs.org/sioc/types#>
select ?endp, ?proto
from <http://demo.openlinksw.com/dataspace>
where
  {
   ?forum a sioct:Weblog .
   ?forum svc:has_service ?svc .
   ?svc svc:service_endpoint ?endp .
   ?svc svc:service_protocol ?proto .
  }
order by ?proto

Dump of all Weblog Posts for a given ODS Member that include content of blog post.

prefix rdf: <http://www.w3.org/1999/02/22-rdf-syntax-ns#>
prefix sioc: <http://rdfs.org/sioc/ns#>
prefix xsd: <http://www.w3.org/2001/XMLSchema#>
prefix dct: <http://purl.org/dc/elements/1.1/>
prefix dcc: <http://purl.org/dc/terms/>
prefix sioct: <http://rdfs.org/sioc/types#>
select ?forum_name, ?post, ?title, ?cr, ?content, ?url
from <http://demo.openlinksw.com/dataspace>
where
   {
    ?forum a sioct:Weblog .
    ?forum sioc:id ?forum_name.
    ?forum sioc:scope_of ?role.
    ?role sioc:function_of <http://demo.openlinksw.com/dataspace/demo#this> .
    ?forum sioc:container_of ?post.
    optional{?post dct:title ?title }.
    optional{?post dcc:created ?cr }.
    optional{?post sioc:link ?url }.
    optional{?post sioc:links_to ?links_to }.
    optional{?post sioc:content ?content}
   }

Dump of all Weblog Posts for a given ODS Member that includes content of blog post plus out-bound links.

prefix rdf: <http://www.w3.org/1999/02/22-rdf-syntax-ns#>
prefix sioc: <http://rdfs.org/sioc/ns#>
prefix sioct: <http://rdfs.org/sioc/types#>
prefix xsd: <http://www.w3.org/2001/XMLSchema#>
prefix dct: <http://purl.org/dc/elements/1.1/>
prefix dcc: <http://purl.org/dc/terms/>
select ?forum_name, ?post, ?title, ?cr, ?content, ?url, ?links_to
from <http://demo.openlinksw.com/dataspace>
where
   {
    ?forum a sioct:Weblog .
    ?forum sioc:id ?forum_name.
    ?forum sioc:scope_of ?role.
    ?role sioc:function_of <http://demo.openlinksw.com/dataspace/demo#this> .
    ?forum sioc:container_of ?post.
    optional{ ?post dct:title ?title }.
    optional{ ?post dcc:created ?cr }.
    optional{ ?post sioc:link ?url }.
    optional{ ?post sioc:links_to ?links_to }.
    optional{?post sioc:content ?content}
  }

Wiki Data Space

The following query scans an entire ODS data space (collection of many application specific data spaces) for properties associated with Entities of Type: Wiki

prefix rdf: <http://www.w3.org/1999/02/22-rdf-syntax-ns#>
prefix sioc: <http://rdfs.org/sioc/ns#>
prefix sioct: <http://rdfs.org/sioc/types#>
select distinct ?attribute
from <http://demo.openlinksw.com/dataspace>
where
  {
     ?forum rdf:type sioct:Wiki .
     ?forum sioc:container_of ?post .
     ?post ?attribute ?o
   }
order by ?attribute

Dump of all Wikiwords for a given Wiki

prefix rdf: <http://www.w3.org/1999/02/22-rdf-syntax-ns#>
prefix sioc: <http://rdfs.org/sioc/ns#>
prefix sioct: <http://rdfs.org/sioc/types#>
prefix xsd: <http://www.w3.org/2001/XMLSchema#>
prefix dct: <http://purl.org/dc/elements/1.1/>
prefix dcc: <http://purl.org/dc/terms/>
select distinct ?forum_name, ?post, ?title, ?link, ?links_to, ?cr
from <http://demo.openlinksw.com/dataspace>
where
   {
    ?forum rdf:type sioct:Wiki .
    ?forum sioc:id ?forum_name.
    ?forum sioc:container_of ?post .
    ?post dct:title ?title.
    optional {?post dcc:created ?cr}.
    optional {?post sioc:link ?link} .
    optional {?post sioc:links_to ?links_to} .
   }
order by ?title

Dump of all WikiWords for a given Wiki including content plus out-bound links

prefix rdf: <http://www.w3.org/1999/02/22-rdf-syntax-ns#>
prefix sioc: <http://rdfs.org/sioc/ns#>
prefix sioct: <http://rdfs.org/sioc/types#>
prefix xsd: <http://www.w3.org/2001/XMLSchema#>
prefix dct: <http://purl.org/dc/elements/1.1/>
prefix dcc: <http://purl.org/dc/terms/>
select ?forum_name, ?post, ?title, ?link, ?links_to, ?cr, ?content
from <http://demo.openlinksw.com/dataspace>
where
   {
    ?forum rdf:type sioct:Wiki .
    ?forum sioc:id ?forum_name.
    ?forum sioc:container_of ?post .
    ?post dct:title ?title.
    optional {?post dcc:created ?cr}.
    optional {?post sioc:link ?link} .
    optional {?post sioc:links_to ?links_to} .
    optional {?post sioc:content ?content}.
   }

List of Web Services (e.g Atom Publishing (SOAP), Moveable Type (XML-RPC) etc.) associated with Wiki Data Space Instances

prefix svc: <http://rdfs.org/sioc/services#>
prefix sioct: <http://rdfs.org/sioc/types#>
select ?endp , ?proto
from <http://demo.openlinksw.com/dataspace>
where
   {
    ?forum a sioct:Wiki.
    ?forum svc:has_service ?svc .
    ?svc svc:service_endpoint ?endp .
    ?svc svc:service_protocol ?proto .
   }
order by ?proto

Calendar Data Space

The following query scans an entire ODS data space (collection of many application specific data spaces) for properties associated with Entities of Type: Calendar

prefix rdf: <http://www.w3.org/1999/02/22-rdf-syntax-ns#>
prefix sioc: <http://rdfs.org/sioc/ns#>
prefix sioct: <http://rdfs.org/sioc/types#>
select distinct ?attribute
from <http://demo.openlinksw.com/dataspace>
where
  {
    ?forum rdf:type sioct:Calendar .
    ?forum sioc:container_of ?post .
    ?post ?attribute ?o
  }
order by ?attribute

Dump of all Events for a given Calendar

prefix rdf: <http://www.w3.org/1999/02/22-rdf-syntax-ns#>
prefix sioc: <http://rdfs.org/sioc/ns#>
prefix sioct: <http://rdfs.org/sioc/types#>
prefix dct: <http://purl.org/dc/elements/1.1/>
prefix dcc: <http://purl.org/dc/terms/>
prefix calr: <http://www.w3.org/2002/12/cal#>
select distinct ?forum_name, ?post, ?title, ?link, ?cr
from <http://demo.openlinksw.com/dataspace>
where
   {
    ?forum rdf:type sioct:Calendar .
    ?forum sioc:id ?forum_name.
    ?forum sioc:container_of ?post .
    ?post rdf:type calr:vevent .
    ?post dct:title ?title.
    optional {?post dcc:created ?cr}.
    optional {?post sioc:link ?link} .
   }

Dump of all Events for a given Calendar including content

prefix rdf: <http://www.w3.org/1999/02/22-rdf-syntax-ns#>
prefix sioc: <http://rdfs.org/sioc/ns#>
prefix sioct: <http://rdfs.org/sioc/types#>
prefix dct: <http://purl.org/dc/elements/1.1/>
prefix dcc: <http://purl.org/dc/terms/>
prefix calr: <http://www.w3.org/2002/12/cal#>
select ?forum_name, ?post, ?title, ?link, ?links_to, ?cr, ?content
from <http://demo.openlinksw.com/dataspace>
where
   {
    ?forum rdf:type sioct:Calendar.
    ?forum sioc:id ?forum_name.
    ?forum sioc:container_of ?post .
    ?post rdf:type calr:vevent .
    optional {?post dct:title ?title}.
    optional {?post dcc:created ?cr}.
    optional {?post sioc:link ?link} .
    optional {?post sioc:links_to ?links_to} .
    optional {?post sioc:content ?content}.
   }

Dump of Events with details for a given Calendar

prefix rdf: <http://www.w3.org/1999/02/22-rdf-syntax-ns#>
prefix sioc: <http://rdfs.org/sioc/ns#>
prefix sioct: <http://rdfs.org/sioc/types#>
prefix dct: <http://purl.org/dc/elements/1.1/>
prefix dcc: <http://purl.org/dc/terms/>
prefix calr: <http://www.w3.org/2002/12/cal#>
select distinct ?forum_name, ?post, ?url, ?summary, ?descr, ?location
from <http://demo.openlinksw.com/dataspace>
where
   {
    ?forum rdf:type sioct:Calendar .
    ?forum sioc:id ?forum_name.
    ?forum sioc:container_of ?post .
    ?post rdf:type calr:vevent .
    optional{?post dct:title ?title}.
    optional{?post calr:url ?url }.
    optional{?post calr:summary ?summary }.
    optional{?post calr:description ?descr }.
    optional{?post calr:dtstart ?start}.
    optional{?post calr:location ?location}.
   }

Feeds / Subscriptions Data Space
(Feed Aggregation)

The following query scans an entire ODS data space (collection of many application specific data spaces) for properties associated with Entities of Type: SubscriptionList

prefix rdf: <http://www.w3.org/1999/02/22-rdf-syntax-ns#>
prefix sioc: <http://rdfs.org/sioc/ns#>
prefix sioct: <http://rdfs.org/sioc/types#>
select distinct ?attribute
from <http://demo.openlinksw.com/dataspace>
where
  {
   ?forum rdf:type sioct:SubscriptionList .
   ?forum sioc:parent_of ?parentf .
   ?parentf sioc:container_of ?post .
   ?post ?attribute ?o
  }
order by ?attribute

Obtaining a dump of all Posts within an ODS-Feeds Data Space

prefix rdf: <http://www.w3.org/1999/02/22-rdf-syntax-ns#>
prefix sioc: <http://rdfs.org/sioc/ns#>
prefix sioct: <http://rdfs.org/sioc/types#>
prefix dct: <http://purl.org/dc/elements/1.1/>
prefix dcc: <http://purl.org/dc/terms/>
select ?forum_name, ?channel, ?item_title, ?created
from <http://demo.openlinksw.com/dataspace>
where
   {
    ?forum a sioct:SubscriptionList;
     sioc:id ?forum_name.
    ?forum sioc:scope_of ?role.
    ?role sioc:function_of <http://demo.openlinksw.com/dataspace/demo#this> .
    ?forum sioc:parent_of ?channel .
    ?channel sioc:container_of ?post .
    optional{ ?post dct:title ?item_title }.
    optional{ ?post dcc:created ?created }.
   }

Obtaining a dump of all Posts within an ODS-Feeds Data Space that includes feed content

prefix rdf: <http://www.w3.org/1999/02/22-rdf-syntax-ns#>
prefix sioc: <http://rdfs.org/sioc/ns#>
prefix sioct: <http://rdfs.org/sioc/types#>
prefix dct: <http://purl.org/dc/elements/1.1/>
prefix dcc: <http://purl.org/dc/terms/>
select ?forum_name, ?channel, ?item_title, ?url, ?created, ?content
from <http://demo.openlinksw.com/dataspace>
where
   {
    ?forum a sioct:SubscriptionList;
     sioc:id ?forum_name.
    ?forum sioc:scope_of ?role.
    ?role sioc:function_of <http://demo.openlinksw.com/dataspace/demo#this> .
    ?forum sioc:parent_of ?channel .
    ?channel sioc:container_of ?post .
    optional{ ?post dct:title ?item_title }.
    optional{ ?post sioc:links_to ?url }.
    optional{ ?post dcc:created ?created }.
    optional{ ?post sioc:content ?content}.
   }

Bookmarks Data Space

The following query scans an entire ODS data space (collection of many application specific data spaces) for properties associated with Entities of Type: BookmarkFolder

prefix rdf: <http://www.w3.org/1999/02/22-rdf-syntax-ns#>
prefix sioc: <http://rdfs.org/sioc/ns#>
prefix sioct: <http://rdfs.org/sioc/types#>
select distinct ?attribute
from <http://demo.openlinksw.com/dataspace>
where
  {
   ?forum a sioct:BookmarkFolder .
   ?forum sioc:container_of ?post .
   ?post ?attribute ?o
  }
order by ?attribute

Dump of all Bookmark Data Space entries for a given ODS Bookmarks Data Space

prefix rdf: <http://www.w3.org/1999/02/22-rdf-syntax-ns#>
prefix sioc: <http://rdfs.org/sioc/ns#>
prefix sioct: <http://rdfs.org/sioc/types#>
prefix dct: <http://purl.org/dc/elements/1.1/>
select distinct ?forum_name, ?post, ?title, ?link, ?url
from <http://demo.openlinksw.com/dataspace>
where
  {
    ?forum a sioct:BookmarkFolder .
    ?forum sioc:id ?forum_name.
    ?forum sioc:scope_of ?role.
    ?role sioc:function_of <http://demo.openlinksw.com/dataspace/demo#this> .
    ?forum sioc:container_of ?post .
    optional{ ?post dct:title ?title }.
    optional{ ?post sioc:link ?link } .
    optional{ ?post sioc:links_to ?url }
   }
order by ?title

List of Web Services (e.g Atom Publishing (SOAP), Moveable Type (XML-RPC) etc.) associated with Bookmarks Data Space Instances

prefix rdf: <http://www.w3.org/1999/02/22-rdf-syntax-ns#>
prefix svc: <http://rdfs.org/sioc/services#>
prefix sioct: <http://rdfs.org/sioc/types#>
select ?endp , ?proto
from <http://demo.openlinksw.com/dataspace>
where
   {
    ?forum a sioct:BookmarkFolder .
    ?forum svc:has_service ?svc .
    ?svc svc:service_endpoint ?endp .
    ?svc svc:service_protocol ?proto .
   }
order by ?proto

AddressBook Data Space

The following query scans an entire ODS data space (collection of many application specific data spaces) for properties associated with Entities of Type: AddressBook

prefix sioc: <http://rdfs.org/sioc/ns#>
prefix sioct: <http://rdfs.org/sioc/types#>
select distinct ?attribute
from <http://demo.openlinksw.com/dataspace>
where
  {
   ?forum a sioct:AddressBook .
   ?forum sioc:container_of ?post .
   ?post ?attribute ?o
  }
order by ?attribute

Dump all AddressBook's members

prefix sioc: <http://rdfs.org/sioc/ns#>
prefix sioct: <http://rdfs.org/sioc/types#>
prefix foaf: <http://xmlns.com/foaf/0.1/>
select ?member, ?id
from <http://demo.openlinksw.com/dataspace>
where
   {
    ?s a sioct:AddressBook;
    sioc:scope_of ?role.
    ?role sioc:function_of ?member.
    ?member sioc:id ?id.
   }

Dump all AddressBook's members friends

prefix rdf: <http://www.w3.org/1999/02/22-rdf-syntax-ns#>
prefix sioc: <http://rdfs.org/sioc/ns#>
prefix sioct: <http://rdfs.org/sioc/types#>
prefix foaf: <http://xmlns.com/foaf/0.1/>
select ?member, ?knows
from <http://demo.openlinksw.com/dataspace>
where
   {
    ?s a sioct:AddressBook;
    sioc:scope_of ?role.
    ?role sioc:function_of ?member.
    ?member foaf:knows ?knows
   }

Dump all AddressBook's contacts

prefix sioc: <http://rdfs.org/sioc/ns#>
prefix sioct: <http://rdfs.org/sioc/types#>
prefix vcd: <http://www.w3.org/2001/vcard-rdf/3.0#>
prefix dct: <http://purl.org/dc/elements/1.1/>
prefix dcc: <http://purl.org/dc/terms/>
select ?FN ?nick ?address ?title ?created ?link ?topic
from <http://demo.openlinksw.com/dataspace>
where
   {
    ?forum a sioct:AddressBook .
    ?forum sioc:container_of ?post .
    optional {?post vcd:FN ?FN }.
    optional {?post vcd:NICKNAME ?nick}.
    optional {?post vcd:ADR ?address}.
    optional {?post dct:title ?title}.
    optional {?post dcc:created ?created}.
    optional {?post sioc:link ?link }.
    optional {?post sioc:topic ?topic } .
   }

List of Web Services (e.g Atom Publishing (SOAP), Moveable Type (XML-RPC) etc.) associated with AddressBook Data Space Instances

prefix rdf: <http://www.w3.org/1999/02/22-rdf-syntax-ns#>
prefix svc: <http://rdfs.org/sioc/services#>
prefix sioct: <http://rdfs.org/sioc/types#>
select ?endp , ?proto
from <http://demo.openlinksw.com/dataspace>
where
   {
    ?forum a sioct:AddressBook .
    ?forum svc:has_service ?svc .
    ?svc svc:service_endpoint ?endp .
    ?svc svc:service_protocol ?proto .
   }
order by ?proto

Dump all properties supported for members imported from Briefcase FOAF uploaded

prefix sioct: <http://rdfs.org/sioc/types#>
prefix sioc: <http://rdfs.org/sioc/ns#>
select distinct ?attribute
from <http://demo.openlinksw.com/dataspace>
where
   {
    ?s a sioct:AddressBook;
    sioc:scope_of ?role.
    ?role sioc:function_of ?member.
    ?member ?attribute ?o
   }

Polls Data Space

The following query scans an entire ODS data space (collection of many application specific data spaces) for properties associated with Entities of Type: ServeyCollection

prefix rdf: <http://www.w3.org/1999/02/22-rdf-syntax-ns#>
prefix sioc: <http://rdfs.org/sioc/ns#>
prefix sioct: <http://rdfs.org/sioc/types#>
select distinct ?attribute
from <http://demo.openlinksw.com/dataspace>
where
  {
   ?forum a sioct:SurveyCollection.
   ?forum sioc:container_of ?post .
   ?post ?attribute ?o
  }
order by ?attribute

Dump of all Polls Posts for a given ODS Member

prefix rdf: <http://www.w3.org/1999/02/22-rdf-syntax-ns#>
prefix sioc: <http://rdfs.org/sioc/ns#>
prefix sioct: <http://rdfs.org/sioc/types#>
prefix xsd: <http://www.w3.org/2001/XMLSchema#>
prefix dct: <http://purl.org/dc/elements/1.1/>
prefix dcc: <http://purl.org/dc/terms/>
select DISTINCT ?forum_name, ?post, ?title ?cr ?url
from <http://demo.openlinksw.com/dataspace>
where
  {
    ?forum a sioct:SurveyCollection.
    ?forum sioc:id ?forum_name.
    ?forum sioc:scope_of ?role.
    ?role sioc:function_of <http://demo.openlinksw.com/dataspace/demo#this> .
    ?forum sioc:container_of ?post.
    optional{ ?post dct:title ?title }.
    optional{ ?post dcc:created ?cr }.
    optional{ ?post sioc:link ?url }.
   }
order by DESC (?cr)

Photo Gallery Data Space

The following query scans an entire ODS data space (collection of many application specific data spaces) for properties associated with Entities of Type: ImageGallery

prefix rdf: <http://www.w3.org/1999/02/22-rdf-syntax-ns#>
prefix sioc: <http://rdfs.org/sioc/ns#>
prefix sioct: <http://rdfs.org/sioc/types#>
select distinct ?attribute
from <http://demo.openlinksw.com/dataspace>
where
  {
   ?forum rdf:type sioct:ImageGallery .
   ?forum sioc:container_of ?post .
   ?post ?attribute ?o
  }
order by ?attribute

Dump of all Data Space entries for a given ODS Photo Gallery including content and out-bound links

prefix rdf: <http://www.w3.org/1999/02/22-rdf-syntax-ns#>
prefix sioc: <http://rdfs.org/sioc/ns#>
prefix sioct: <http://rdfs.org/sioc/types#>
prefix xsd: <http://www.w3.org/2001/XMLSchema#>
prefix dct: <http://purl.org/dc/elements/1.1/>
prefix dcc: <http://purl.org/dc/terms/>
select ?forum_name, ?post, ?title, ?link, ?links_to, ?cr, ?content
from <http://demo.openlinksw.com/dataspace>
where
  {
    ?forum rdf:type sioct:ImageGallery .
    ?forum sioc:id ?forum_name.
    ?forum sioc:container_of ?post .
    optional {?post dct:title ?title}.
    optional {?post dcc:created ?cr}.
    optional {?post sioc:link ?link} .
    optional {?post sioc:links_to ?links_to} .
    optional {?post sioc:content ?content}
   }

List of Web Services (e.g Atom Publishing (SOAP), Moveable Type (XML-RPC) etc.) associated with Gallery Data Space Instances

prefix rdf: <http://www.w3.org/1999/02/22-rdf-syntax-ns#>
prefix svc: <http://rdfs.org/sioc/services#>
prefix sioct: <http://rdfs.org/sioc/types#>
select ?endp , ?proto
from <http://demo.openlinksw.com/dataspace>
where
  {
    ?forum a sioct:ImageGallery .
    ?forum svc:has_service ?svc .
    ?svc svc:service_endpoint ?endp .
    ?svc svc:service_protocol ?proto .
   }
order by ?proto

Community (Group Mode) Data Space

The following query scans an entire ODS data space (collection of many application specific data spaces) for properties associated with Entities of Type: Community

prefix rdf: <http://www.w3.org/1999/02/22-rdf-syntax-ns#>
prefix sioc: <http://rdfs.org/sioc/ns#>
prefix sioct: <http://rdfs.org/sioc/types#>
select distinct ?attribute
from <http://demo.openlinksw.com/dataspace>
where
  {
   ?forum rdf:type sioc:Community .
   ?forum sioc:has_part ?parentf .
   ?parentf sioc:container_of ?post .
   ?post ?attribute ?o
  }
order by ?attribute

Dump of all Data Space entries for a given ODS Community

prefix rdf: <http://www.w3.org/1999/02/22-rdf-syntax-ns#>
prefix sioc: <http://rdfs.org/sioc/ns#>
prefix dct: <http://purl.org/dc/elements/1.1/>
select ?post ?title
from <http://demo.openlinksw.com/dataspace>
where
   {
    ?forum rdf:type sioc:Community .
    ?forum sioc:has_part ?parentf .
    ?parentf sioc:container_of ?post .
    optional{?post dct:title ?title} .
   }

Briefcase Data Space

The following query scans an entire ODS data space (collection of many application specific data spaces) for properties associated with Entities of Type: Briefcase

prefix rdf: <http://www.w3.org/1999/02/22-rdf-syntax-ns#>
prefix sioc: <http://rdfs.org/sioc/ns#>
prefix sioct: <http://rdfs.org/sioc/types#>
select distinct ?attribute
from <http://demo.openlinksw.com/dataspace>
where
  {
   ?forum rdf:type sioct:Briefcase .
   ?forum sioc:container_of ?post .
   ?post ?attribute ?o
  }
order by ?attribute

List of Web Services (e.g Atom Publishing (SOAP), Moveable Type (XML-RPC) etc.) associated with Briefcase Data Space Instances

prefix rdf: <http://www.w3.org/1999/02/22-rdf-syntax-ns#>
prefix svc: <http://rdfs.org/sioc/services#>
prefix sioct: <http://rdfs.org/sioc/types#>
select ?endp , ?proto
from <http://demo.openlinksw.com/dataspace>
where
  {
    ?forum a sioct:Briefcase .
    ?forum svc:has_service ?svc .
    ?svc svc:service_endpoint ?endp .
    ?svc svc:service_protocol ?proto .
   }
order by ?proto

Dump of all Briefcase Items from special "Public" folder

prefix rdf: <http://www.w3.org/1999/02/22-rdf-syntax-ns#>
prefix sioc: <http://rdfs.org/sioc/ns#>
prefix sioct: <http://rdfs.org/sioc/types#>
prefix xsd: <http://www.w3.org/2001/XMLSchema#>
prefix dct: <http://purl.org/dc/elements/1.1/>
prefix dcc: <http://purl.org/dc/terms/>
select DISTINCT ?forum_name, ?post, ?title, ?cr, ?url, ?links_to
from <http://demo.openlinksw.com/dataspace>
where
  {
    ?forum a sioct:Briefcase .
    ?forum sioc:id ?forum_name.
    ?forum sioc:container_of ?post.
    optional { ?post dct:title ?title }.
    optional { ?post dcc:created ?cr }.
    optional { ?post sioc:link ?url }.
    optional { ?post sioc:links_to ?links_to }.
   }
order by DESC (?cr)

Discussion / Conversation Data Space

The following query scans an entire ODS data space (collection of many application specific data spaces) for properties associated with Entities of Type: MessageBoard

prefix rdf: <http://www.w3.org/1999/02/22-rdf-syntax-ns#>
prefix sioc: <http://rdfs.org/sioc/ns#>
prefix sioct: <http://rdfs.org/sioc/types#>
select distinct ?attribute
from <http://demo.openlinksw.com/dataspace>
where
  {
   ?forum rdf:type sioct:MessageBoard .
   ?forum sioc:container_of ?post .
   ?post ?attribute ?o
  }
order by ?attribute

Discussion list

prefix rdf: <http://www.w3.org/1999/02/22-rdf-syntax-ns#>
prefix sioc: <http://rdfs.org/sioc/ns#>
prefix sioct: <http://rdfs.org/sioc/types#>
prefix dct: <http://purl.org/dc/elements/1.1/>
prefix dcc: <http://purl.org/dc/terms/>
select distinct ?forum_name, ?post, ?title, ?mod_time, ?create_time, ?url
from <http://demo.openlinksw.com/dataspace>
where
  {
    ?forum a sioct:MessageBoard ;
     sioc:id ?forum_name.
    optional{ ?forum sioc:container_of ?post } .
    optional{ ?post dct:title ?title } .
    optional{ ?post dcc:modified ?mod_time } .
    optional{ ?post dcc:created ?create_time } .
    optional{ ?post sioc:link ?url } .
   }
limit 10

Obtaining a dump of all Posts within a specific ODS-Discussion Data Space that includes discussion content

prefix rdf: <http://www.w3.org/1999/02/22-rdf-syntax-ns#>
prefix sioc: <http://rdfs.org/sioc/ns#>
prefix sioct: <http://rdfs.org/sioc/types#>
prefix dct: <http://purl.org/dc/elements/1.1/>
prefix dcc: <http://purl.org/dc/terms/>
select ?forum_name, ?post, ?title, ?mod_time, ?create_time, ?url, ?content
from <http://demo.openlinksw.com/dataspace>
where
  {
    ?forum a sioct:MessageBoard ;
     sioc:id ?forum_name FILTER REGEX(?forum_name,".*demo*.").
    optional{ ?forum sioc:container_of ?post } .
    optional{ ?post dct:title ?title } .
    optional{ ?post dcc:modified ?mod_time } .
    optional{ ?post dcc:created ?create_time } .
    optional{ ?post sioc:link ?url } .
    optional{ ?post sioc:content ?content}.
}

prefix rdf: <http://www.w3.org/1999/02/22-rdf-syntax-ns#>
prefix sioc: <http://rdfs.org/sioc/ns#>
prefix sioct: <http://rdfs.org/sioc/types#>
prefix dct: <http://purl.org/dc/elements/1.1/>
prefix dcc: <http://purl.org/dc/terms/>
select distinct ?forum_name, ?post, ?title, ?mod_time, ?create_time, ?url
from <http://demo.openlinksw.com/dataspace>
where
  {
    ?forum rdf:type sioct:MessageBoard.
    optional{ ?forum sioc:id ?forum_name. FILTER REGEX(?forum_name,".*demo*.") }.
    optional{ ?forum sioc:container_of ?post } .
    optional{ ?post dct:title ?title } .
    optional{ ?post dcc:modified ?mod_time } .
    optional{ ?post dcc:created ?create_time } .
    optional{ ?post sioc:link ?url } .
   }
limit 10

Dump of Wiki Posts with "Conversation" Feature Enabled

prefix rdf: <http://www.w3.org/1999/02/22-rdf-syntax-ns#>
prefix sioc: <http://rdfs.org/sioc/ns#>
prefix sioct: <http://rdfs.org/sioc/types#>
prefix dct: <http://purl.org/dc/elements/1.1/>
prefix dcc: <http://purl.org/dc/terms/>
select distinct ?forum_name, ?post, ?title, ?mod_time, ?create_time, ?url
from <http://demo.openlinksw.com/dataspace>
where
  {
    ?forum rdf:type sioct:MessageBoard ;
     sioc:id ?forum_name FILTER REGEX(?forum_name,".*mywiki*.").
    optional{ ?forum sioc:container_of ?post } .
    optional{ ?post dct:title ?title } .
    optional{ ?post dcc:modified ?mod_time } .
    optional{ ?post dcc:created ?create_time } .
    optional{ ?post sioc:link ?url } .
   }

These SPARQL queries join data across serveral ODS data spaces.

Data for analyzing Tags associated with Posts that also demonstrates the use of the SKOS ontology for describing Post topics (tags)

prefix rdf: <http://www.w3.org/1999/02/22-rdf-syntax-ns#>
prefix skos: <http://www.w3.org/2004/02/skos/core#>
prefix sioc: <http://rdfs.org/sioc/ns#>
prefix sioct: <http://rdfs.org/sioc/types#>
prefix dc: <http://purl.org/dc/elements/1.1/>
select ?title, ?tag, ?topic
from <http://demo.openlinksw.com/dataspace>
where
   {
    ?s a sioc:Item.
    optional { ?s dc:title ?title }.
    ?s sioc:id ?id .
    optional { ?s sioc:topic ?topic .
               ?topic rdf:type skos:Concept .
               ?topic skos:prefLabel ?tag }
   }

People Network Construction that integrates data from both the FOAF and SKOS ontologies

prefix rdf: <http://www.w3.org/1999/02/22-rdf-syntax-ns#>
prefix sioc: <http://rdfs.org/sioc/ns#>
prefix sioct: <http://rdfs.org/sioc/types#>
prefix xsd: <http://www.w3.org/2001/XMLSchema#>
prefix dct: <http://purl.org/dc/elements/1.1/>
prefix dcc: <http://purl.org/dc/terms/>
prefix skos: <http://www.w3.org/2004/02/skos/core#>
prefix foaf: <http://xmlns.com/foaf/0.1/>
select DISTINCT ?forum_name, ?post, ?title, ?cr, ?url, ?links_to, ?tag, ?nick, ?gender, ?org, ?geodata
from <http://demo.openlinksw.com/dataspace>
where
   {
    ?forum a sioct:Weblog .
    ?forum sioc:id ?forum_name.
    optional {?forum sioc:scope_of ?role } .
    optional { ?role sioc:function_of "<http://demo.openlinksw.com/dataspace/demo#this>" } .
    ?forum sioc:container_of ?post.
    optional { ?post dct:title ?title.
     ?post dcc:created ?cr.
     ?post sioc:link ?url.
     ?post sioc:links_to ?links_to.
     ?post foaf:maker ?maker } .
    optional { ?maker foaf:nick ?nick } .
    optional { ?maker foaf:name ?fname } .
    optional { ?maker foaf:gender ?gender } .
    optional { ?maker foaf:based_near ?geodata } .
    optional { ?maker foaf:organization ?org } .
    optional {?post sioc:topic ?topic .
     ?topic rdf:type skos:Concept .
     ?topic skos:prefLabel ?tag }
   }

People Network Construction using data from Post Comments

prefix sioc: <http://rdfs.org/sioc/ns#>
prefix sioct: <http://rdfs.org/sioc/types#>
prefix foaf: <http://xmlns.com/foaf/0.1/>
prefix xsd: <http://www.w3.org/2001/XMLSchema#>
prefix rdfs: <http://www.w3.org/2000/01/rdf-schema#>
prefix rdf: <http://www.w3.org/1999/02/22-rdf-syntax-ns#>
prefix dc: <http://purl.org/dc/elements/1.1/>
prefix dcterms: <http://purl.org/dc/terms/>
select DISTINCT ?post, ?post_sioc, ?post_author, ?post_title, ?post_date, ?reply
from <http://demo.openlinksw.com/dataspace>
where
  {
    ?post sioc:has_creator ?_x .
    ?_x sioc:id ?post_author .
    optional { ?post rdfs:seeAlso ?post_sioc } .
    optional { ?post sioc:has_reply ?reply } .
    optional { ?post dcterms:created ?post_date } .
    optional { ?post dc:title ?post_title }
  }

CONSTRUCT based SPARQL queries are very useful when trying to expose RDF (via a SPARQL Endpoint) to RDF Data Set consumers that do not support SPARQL. In a sense, the SPARQL CONSTRUCT statements as part of a SPARQL Protocol payload deliver a Data Web (Web 3.0) Experience to Interactive-Web Clients (Web 1.0).

People Network returned as an RDF Graph

prefix sioc: <http://rdfs.org/sioc/ns#>
prefix sioct: <http://rdfs.org/sioc/types#>
prefix foaf: <http://xmlns.com/foaf/0.1/>
prefix xsd: <http://www.w3.org/2001/XMLSchema#>
prefix rdfs: <http://www.w3.org/2000/01/rdf-schema#>
prefix rdf: <http://www.w3.org/1999/02/22-rdf-syntax-ns#>
prefix dc: <http://purl.org/dc/elements/1.1/>
prefix dcterms: <http://purl.org/dc/terms/>
CONSTRUCT
  {
    ?post sioc:has_creator ?_x .
    ?_x sioc:id ?post_author .
    ?post rdfs:seeAlso ?post_sioc .
    ?post sioc:has_reply ?reply .
    ?post dcterms:created ?post_date .
    ?post dc:title ?post_title .
  }
from <http://demo.openlinksw.com/dataspace>
where
   {
    ?post sioc:has_creator ?_x .
    ?_x sioc:id ?post_author .
    optional{ ?post rdfs:seeAlso ?post_sioc } .
    optional{ ?post sioc:has_reply ?reply } .
    optional{ ?post dcterms:created ?post_date } .
    optional{ ?post dc:title ?post_title }
  }
limit 10

Discussions posts details returned as an RDF Graph

prefix sioc: <http://rdfs.org/sioc/ns#>
prefix sioct: <http://rdfs.org/sioc/types#>
prefix rdf: <http://www.w3.org/1999/02/22-rdf-syntax-ns#>
prefix dcterms: <http://purl.org/dc/terms/>
CONSTRUCT
  {
   ?post dcterms:created ?created .
   ?post sioc:link ?link .
   ?post sioc:title ?title .
  }
from <http://demo.openlinksw.com/dataspace>
where
   {
    ?forum a sioct:MessageBoard .
    ?post sioc:has_container ?forum .
    optional { ?post dcterms:created ?created } .
    optional { ?post sioc:link ?link } .
    optional { ?post sioc:title ?title }
   }
limit 10

List of all registered Dataspace members's home pages URLs returned as an RDF Graph

prefix foaf: <http://xmlns.com/foaf/0.1/>
prefix rdf: <http://www.w3.org/1999/02/22-rdf-syntax-ns#>
prefix sioc: <http://rdfs.org/sioc/ns#>
prefix sioct: <http://rdfs.org/sioc/types#>
CONSTRUCT
  {
    ?x rdf:type sioc:User .
  }
from <http://demo.openlinksw.com/dataspace>
where
  {
    ?x rdf:type sioc:User .
  }
limit 10

Gallery images details for user "demo" returned as an RDF Graph

prefix rdf: <http://www.w3.org/1999/02/22-rdf-syntax-ns#>
prefix sioc: <http://rdfs.org/sioc/ns#>
prefix sioct: <http://rdfs.org/sioc/types#>
prefix skos: <http://www.w3.org/2004/02/skos/core#>
prefix xsd: <http://www.w3.org/2001/XMLSchema#>
prefix dc: <http://purl.org/dc/elements/1.1/>
prefix dcterms: <http://purl.org/dc/terms/>
CONSTRUCT
  {
    ?post dc:title ?title .
    ?post sioc:link ?link .
    ?post sioc:links_to ?links_to .
    ?post sioc:topic ?topic .
    ?post dcterms:created ?cr
  }
from <http://demo.openlinksw.com/dataspace>
where
  {
    ?post rdf:type sioc:Item .
    optional { ?post dc:title ?title } .
    optional { ?post sioc:link ?link } .
    optional { ?post sioc:links_to ?links_to } .
    optional { ?post dcterms:created ?cr } .
    optional { ?post sioc:topic ?topic }.
    optional { ?topic skos:prefLabel ?tag }.
    ?post sioc:has_container ?forum .
    ?forum a sioct:ImageGallery .
    ?forum sioc:scope_of ?role.
    ?role sioc:function_of ?member.
    ?member sioc:id "demo"
  }

Community posts title and date details returned as an RDF Graph

prefix rdf: <http://www.w3.org/1999/02/22-rdf-syntax-ns#>
prefix sioc: <http://rdfs.org/sioc/ns#>
prefix sioct: <http://rdfs.org/sioc/types#>
prefix xsd: <http://www.w3.org/2001/XMLSchema#>
prefix dc: <http://purl.org/dc/elements/1.1/>
prefix dcterms: <http://purl.org/dc/terms/>
CONSTRUCT
  {
    ?post dc:title ?title .
    ?post dcterms:created ?date
  }
from <http://demo.openlinksw.com/dataspace>
where
  {
    ?forum rdf:type sioc:Community .
    ?forum sioc:has_part ?parentf .
    ?parentf sioc:container_of ?post .
    optional { ?post dc:title ?title } .
    optional { ?post dcterms:created ?date } .
  }

Describe all Weblog Data Spaces

prefix rdf: <http://www.w3.org/1999/02/22-rdf-syntax-ns#>
prefix sioct: <http://rdfs.org/sioc/types#>
DESCRIBE ?forum from <http://demo.openlinksw.com/dataspace>
where
  {
    ?forum rdf:type sioct:Weblog .
  }

INSERT into Graph

sparql define input:default-graph-uri <http://mygraph.com>
insert { <http://myopenlink.net/dataspace/Kingsley#this>
         <http://www.w3.org/1999/02/22-rdf-syntax-ns#type>
         <http://rdfs.org/sioc/ns#User> };

INSERT with expressions to calculate fields of new triples

sparql insert into graph <http://mygraph.com>
  {
   ?s <http://rdfs.org/sioc/ns#id> `iri (bif:concat (str (?o), "Idehen"))`
  }
where { ?s <http://rdfs.org/sioc/ns#id> ?o };

'Modify graph' may be used as a sort of 'update' operation.

sparql modify graph <http://mygraph.com> delete
   {
    ?s <http://www.w3.org/1999/02/22-rdf-syntax-ns#type> ?o
   } insert
   {
    ?s <http://www.w3.org/1999/02/22-rdf-syntax-ns#type1> ?o
   }
   where
   {
    ?s <http://www.w3.org/1999/02/22-rdf-syntax-ns#type> ?o
   };

sparql delete from graph <http://mygraph.com>
   {
    <http://myopenlink.net/dataspace/Caroline#this> <http://www.w3.org/1999/02/22-rdf-syntax-ns#type1> <http://rdfs.org/sioc/ns#User>
   };

prefix dct: <http://purl.org/dc/elements/1.1/>
PREFIX sioct: <http://rdfs.org/sioc/types#>
prefix sioc: <http://rdfs.org/sioc/ns#>
prefix rdfs: <http://www.w3.org/2000/01/rdf-schema#>
select *
from <http://demo.openlinksw.com/dataspace>
where
  {
   ?f a sioct:WishList.
   ?f sioc:container_of ?s .
   ?s dct:description ?descr .
   ?s dct:title ?title .
   ?s sioc:has_creator ?creator .
   ?s rdfs:label ?label .
  }

prefix dct: <http://purl.org/dc/elements/1.1/>
PREFIX sioct: <http://rdfs.org/sioc/types#>
prefix sioc: <http://rdfs.org/sioc/ns#>
prefix rdfs: <http://www.w3.org/2000/01/rdf-schema#>
select *
from <http://demo.openlinksw.com/dataspace>
where
  {
   ?f a sioct:OfferList.
   ?f sioc:container_of ?s .
   ?s dct:description ?descr .
   ?s dct:title ?title .
   ?s sioc:has_creator ?creator .
   ?s rdfs:label ?label .
   ?s sioc:link ?link .
  }

Social Connections a la LinkedIn

Show the people a person directly or indirectly knows. Sort by distance and count of connections of the known person:

select ?o ?dist ( ( select count ( * )
                    where { ?o foaf:knows ?xx } ) )
where
   {
    {
     select ?s ?o where
     {
      ?s foaf:knows ?o
     }
    }
    option ( transitive,
            t_distinct,
            t_in ( ?s ) ,
            t_out ( ?o ) ,
            t_min ( 1 ) ,
            t_max ( 4 ) ,
            t_step ( 'step_no' ) as ?dist
           ) .
    filter ( ?s= <http://myopenlink.net/dataspace/person/kidehen#this> )
   }
order by ?dist
desc 3
limit 50

Connection Between

Given two people, find what chain of acquaintances links them together. For each step in the chain show the person linked to, the graph linking this person to the previous person, the number of the step and the number of the path. Note that there may be many paths through which the people are linked.

select ?link ?g ?step ?path
where
   {
     {
       select ?s ?o ?g
       where
         {
           graph ?g
         {
       ?s foaf:knows ?o
       }
     }
     }
     option ( transitive,
              t_distinct,
              t_in ( ?s ) ,
              t_out ( ?o ) ,
              t_no_cycles,
              T_shortest_only,
              t_step ( ?s ) as ?link,
              t_step ( 'path_id' ) as ?path,
              t_step ( 'step_no' ) as ?step,
              t_direction 3 ) .
     filter ( ?s= <http://myopenlink.net/dataspace/person/kidehen#this> && ?o = <http://www.advogato.org/person/mparaz/foaf.rdf#me> )
     }
limit 20

References

• Query ODS Data Spaces using SPARQL and Atom OWL Ontology
• Query ODS Data Spaces using SPARQL and SKOS Ontology
• Query ODS Data Spaces using SPARQL and FOAF Ontology
• Query ODS Data Spaces using SPARQL and Annotea Ontology
• ODS SPARQL Samples
• Northwind SPARQL Reference
• Query Virtuoso Tutorials using SPARQL
• Query Virtuoso Documentation using SPARQL
• WordPress SIOC Reference
• MedaWiki SIOC Reference
• PHPBB SIOC Reference
• Drupal SIOC Reference

• SPARQL - Query Language
• SPARQL - Protocol
• SPARQL - XML based Results Format

• Virtuoso SPARQL OAuth Tutorial
• SPARQL Tutorial - Clark+Prasia & University of Manchester Tutorial
• Jena SPARQL Tutorial

• Virtuoso SPARUL
• Virtuoso SPARQL